The XSL stylesheet for CGIF from original Haskell data model.

<?xml version="1.0"?>
<xsl:stylesheet   xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="text"/>
<xsl:variable name="newline">
   &#xD;&#xA;
</xsl:variable>
<xsl:template match="/CGFile/CG">
  <xsl:if test="position()!=1">
     <xsl:value-of select="$newline"/>.<xsl:value-of select="$newline"/>
   </xsl:if>
   <xsl:apply-templates/>
</xsl:template>
<xsl:template match="CNode|OutArc|InArc|Input|Output">
  <xsl:choose>
   <xsl:when test="count(*)&gt;0">
        [
        <xsl:choose>
            <xsl:when test="Label">
               <xsl:value-of select="Label"/>
               <xsl:if test="string(@CoRef)">*<xsl:value-of select="@CoRef"/>
               </xsl:if>
               <xsl:apply-templates select="*"/>
            </xsl:when>
            <xsl:when test="LambdaExpression">
                 (lambda(
                <xsl:for-each select="*/Param">
                    <xsl:if test="position()!=1">,</xsl:if>
                    <xsl:value-of select="Label"/>*<xsl:value-of select="@CoRef"/>
                 </xsl:for-each>
                 )
                <xsl:apply-templates select="*/CG"/>)
            </xsl:when>
          </xsl:choose>
           ]
       </xsl:when>
       <xsl:otherwise>?<xsl:value-of select="@CoRef"/>
       </xsl:otherwise>
  </xsl:choose>
</xsl:template>
<xsl:template match="Label"><xsl:value-of select="*"/></xsl:template>
<xsl:template match="ANode">&lt;<xsl:value-of select="Label"/> <xsl:apply-templates/>&gt;</xsl:template>
<xsl:template match="NNode">~[<xsl:apply-templates/>]</xsl:template>
<xsl:template match="Referent">:<xsl:apply-templates/></xsl:template>
<xsl:template match="RNode">
   (
    <xsl:choose>
       <xsl:when test="Label">
               <xsl:value-of select="Label"/>
       </xsl:when>
        <xsl:when test="LambdaExpression">
            (lambda(
           <xsl:for-each select="*/Param">
                <xsl:if test="position()!=1">,</xsl:if>
                <xsl:value-of select="Label"/>*<xsl:value-of select="@CoRef"/>
           </xsl:for-each>
                          )
     <xsl:apply-templates select="*/CG"/>
           )
       </xsl:when>
     </xsl:choose>
    <xsl:apply-templates select="InArc|OutArc"/>
  )
</xsl:template>
<xsl:template match="Name">'<xsl:value-of select = "."/>'</xsl:template>
<xsl:template match="Marker">#<xsl:value-of select = "."/></xsl:template>
<xsl:template match="LitString">&quot;<xsl:value-of select = "."/>&quot;</xsl:template>
<xsl:template match="Set">
   {
   <xsl:for-each select="Literal">
   <xsl:if test="position()!=1">,</xsl:if>
   <xsl:apply-templates/>
   </xsl:for-each>
   }
</xsl:template>
<xsl:template match="Tuple">
   &lt;
  <xsl:for-each select="Literal">
    <xsl:if test="position()!=1">,</xsl:if>
    <xsl:apply-templates/>
  </xsl:for-each>
  &gt;
</xsl:template>
<xsl:template match="List">
  (
  <xsl:for-each select="Literal">
     <xsl:if test="position()!=1">,</xsl:if>
    <xsl:apply-templates/>
  </xsl:for-each>
  )
</xsl:template>
<xsl:template match="Array">
  [
  <xsl:for-each select="Literal">
    <xsl:if test="position()!=1">,</xsl:if>
    <xsl:apply-templates/>
  </xsl:for-each>
  ]
</xsl:template>
<xsl:template match="Quantifier/Number">@+<xsl:value-of select="."/></xsl:template>
<xsl:template match="Quantifier/Type">@<xsl:value-of select="."/></xsl:template>
<xsl:template match="text()"/>
</xsl:stylesheet>